Add new script for smart monitoring

zabbix_conf/smart.conf

@@ -5,3 +5,7 @@ UserParameter=hardware.disk.smart.discovery,/usr/bin/sudo /var/lib/zabbix/bin/di
 # Takes two args: the drives to check, and the value to get
 # eg: hardward.disk.smart[/dev/sda,Reallocated_Sector_Ct]
 UserParameter=hardware.disk.smart[*],/usr/bin/sudo /var/lib/zabbix/bin/check_smart_sudo $1 $2
+
+# New smart disk discovery/monitoring
+UserParameter=stor.dev.discovery[*]=/usr/bin/sudo /var/lib/zabbix/bin/disco_stor_dev_sudo
+UserParameter=stor.dev.info[*]=/usr/bin/sudo /var/lib/zabbix/bin/check_stor_dev_sudo --dev "$1" --type "$2"

zabbix_scripts/check_stor_dev_sudo

@@ -0,0 +1,112 @@
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+use JSON;
+use Getopt::Long;
+use File::Which;
+
+my $dev    =  undef;
+my $type   = 'auto';
+my $what   = 'json';
+my $pretty = 0;
+
+GetOptions(
+  'device=s' => \$dev,
+  'type=s'   => \$type,
+  'what=s'   => \$what,
+  'pretty'   => \$pretty
+);
+
+if (not defined $dev or $dev !~ m|^/dev/\w+(/\w+)?$| or not -e $dev){
+  print "Invalid --device\n";
+  exit 1;
+} elsif ($what !~ m/^\w+$/){
+  print "Invalid --what\n";
+  exit 1;
+} elsif ($type !~ m/^\w+\+*\w+(,\w+)*$/){
+  print "Invalid --type\n";
+  exit 1;
+}
+
+my $json = {
+  temperature_celsius      => -1,
+  power_on_hours           => -1,
+  power_cycle_count        => -1,
+  reallocated_sector_count => -1,
+  current_pending_sector   => -1,
+  offline_uncorrectable    => -1,
+  percent_lifetime_remain  => -1,
+  firmware_version         => -1
+};
+my $smartctl = which('smartctl');
+
+sub print_out {
+  if ($what eq 'json'){
+    print to_json($json, { pretty => $pretty });
+    exit 0;
+  } elsif (defined $json->{$what}){
+    print $json->{$what} . "\n";
+    exit 0;
+  } else {
+    print "ZBX_NOTSUPPORTED\n";
+    exit 1;
+  }
+}
+
+sub get_smart_attr {
+  my $smart = shift;
+  my $attr  = shift;
+
+  if (defined $smart->{ata_smart_attributes}->{table}){
+    foreach (@{$smart->{ata_smart_attributes}->{table}}){
+      if ($_->{name} eq $attr){
+        return $_;
+      }
+    }
+  }
+  return undef;
+}
+
+if (not defined $smartctl){
+  $what = 'error';
+  print_out();
+}
+
+my $data = from_json(qx($smartctl -a $dev -d $type --json=c));
+
+if (defined $data->{temperature}->{current}){
+  $json->{temperature_celsius} = $data->{temperature}->{current};
+}
+
+if (defined $data->{power_on_time}->{hours}){
+  $json->{power_on_hours} = $data->{power_on_time}->{hours};
+}
+
+if (defined $data->{power_cycle_count}){
+  $json->{power_cycle_count} = $data->{power_cycle_count};
+}
+
+if (defined $data->{firmware_version}){
+  $json->{firmware_version} = $data->{firmware_version};
+}
+
+my ($pending, $realloc, $offline, $remain);
+if ($pending = get_smart_attr($data, 'Current_Pending_Sector')){
+  $json->{current_pending_sector} = $pending->{raw}->{value};
+}
+
+if ($realloc = get_smart_attr($data, 'Reallocated_Sector_Ct') || get_smart_attr($data, 'Reallocated_Event_Count')){
+  $json->{reallocated_sector_count} = $realloc->{raw}->{value};
+}
+
+if ($offline = get_smart_attr($data, 'Offline_Uncorrectable')){
+  $json->{offline_uncorrectable} = $offline->{raw}->{value};
+}
+
+if ($remain = get_smart_attr($data, 'Percent_Lifetime_Remain')){
+  $json->{percent_lifetime_remain} = $remain->{value};
+} elsif ($remain = get_smart_attr($data, 'Wear_Leveling_Count')) {
+  $json->{percent_lifetime_remain} = $remain->{value};
+}
+print_out();

zabbix_scripts/disco_stor_dev_sudo

@@ -0,0 +1,61 @@
+#!/usr/bin/perl
+
+use strict;
+use JSON;
+use Getopt::Long;
+use Data::Dumper;
+use File::Which;
+
+my $pretty = 0;
+
+GetOptions(
+  'pretty' => \$pretty
+);
+
+my $smartctl = which('smartctl');
+my $json = [];
+
+sub print_out {
+  print to_json($json, { pretty => $pretty });
+}
+
+if (not defined $smartctl){
+  print_out();
+  exit 0;
+}
+
+my $smart_scan = from_json(qx($smartctl --scan-open --json=c));
+
+if (not defined $smart_scan){
+  print_out();
+  exit 0;
+}
+
+foreach my $device (@{$smart_scan->{devices}}){
+  my ($model, $sn, $has_smart) = "";
+  my $smart_info = from_json(qx($smartctl -i $device->{name} -d $device->{type} --json=c));
+
+  if (defined $smart_info){
+    $model     = $smart_info->{model_name};
+    $sn        = $smart_info->{serial_number};
+    $has_smart = (
+      $smart_info->{in_smartctl_database} or (
+        defined $smart_info->{smart_support} and
+        $smart_info->{smart_support}->{available} and
+        $smart_info->{smart_support}->{enabled}
+      )
+    ) ? 1 : 0;
+  }
+
+  push @{$json}, {
+    '{#STOR_DEV_NAME}'  => $device->{name},
+    '{#STOR_DEV_DESC}'  => $device->{info_name},
+    '{#STOR_DEV_TYPE}'  => $device->{type},
+    '{#STOR_DEV_PROTO}' => $device->{protocol},
+    '{#STOR_DEV_MODEl}' => $model,
+    '{#STOR_DEV_SN}'    => $sn,
+    '{#STOR_DEV_SMART}' => int $has_smart
+  };
+}
+
+print_out();